एक्सेल यदि OR के साथ सूत्र है, # एन / ए से बचें - एक्सेल, if-statement, एक्सेल-फॉर्मूला

Currently facing a problem, long story short:मैं ओआर-फ़ंक्शन का उपयोग करके, 2 सूत्रों को एक में जोड़ना चाहता हूं, लेकिन यदि 2 स्थितियों में से कोई एक मौजूद नहीं है, तो यह मुझे # एन / ए वापस देता है। वहां 3 स्थितियां हो सकती हैं: "एमटीआई", "एमटीआई जेड" और "एमटीओ"। मुझे यह क्या चाहिए कि फॉर्मूला कॉलम एल में किसी भी संयोजन के लिए "एमटीआई" या "एमटीआई जेड" के साथ खोज करे (शायद यह भी हो सकता है दोनों हो) और यदि वह संयोजन मौजूद है, तो 1 वापस दें। यदि नहीं (तो केवल एमटीओ मौजूद है) तो 0 को वापस करें (इस मामले में यह # एन / ए होगा, लेकिन मैं इसे या तो आईएसएनए या आईएफईआरआरओआर के साथ ठीक कर सकता हूं) ।

फॉर्मूला 1 है:

=IF(CONCATENATE(A2,B2,"MTI")=INDEX(L:L,MATCH(CONCATENATE(A2,B2,"MTI"),L:L,0),0),1,0)

फॉर्मूला 2 है

=IF(CONCATENATE(A2,B2,"MTI Z")=INDEX(L:L,MATCH(CONCATENATE(A2,B2,"MTI Z"),L:L,0),0),1,0)

दोनों सूत्र काम करते हैं, क्रमश: "एमटीआई" या "एमटीआई जेड" होने पर "1" वापस देते हैं

हालांकि, जब मैं उन्हें गठबंधन करने की कोशिश करता हूं, यदि सूची में से 2 में से कोई अस्तित्व में नहीं है, तो यह मुझे # एन / ए देता है, भले ही मैं OR का उपयोग कर रहा हूं (जो बताएगा कि कम से कम 1 में से 1 मौजूद है, आगे बढ़ें)।

=IF(OR(CONCATENATE(A2,B2,"MTI Z")=INDEX(L:L,MATCH(CONCATENATE(A2,B2,"MTI Z"),L:L,0),0)
,CONCATENATE(A2,B2,"MTI")=INDEX(L:L,MATCH(CONCATENATE(A2,B2,"MTI"),L:L,0),0)),1,0)

मैं अपना फॉर्मूला कैसे समायोजित कर सकता हूं ताकि यह काम करे?

उत्तर:

जवाब के लिए 3 № 1

यह थोड़ा और आगे सीधे है:

=SIGN(COUNTIF(L:L,CONCATENATE(A2,B2,"MTI*")))

जवाब के लिए 2 № 2

इन सूत्रों में से प्रत्येक को लपेटें IFERROR([formula],0)


उत्तर № 3 के लिए 1

दो IFERROR "रैपर" जोड़ने का प्रयास करें ताकि जब कोई मिलान न हो, तो # N / A नहीं, तो आप FALSE लौटाएं।

=IF(OR(IFERROR(CONCATENATE(A2,B2,"MTI Z")=INDEX(L:L, MATCH(CONCATENATE(A2,B2, "MTI Z"), L:L, 0)), FALSE),
IFERROR(CONCATENATE(A2,B2,"MTI")=INDEX(L:L, MATCH(CONCATENATE(A2,B2,"MTI"), L:L, 0)), FALSE)),
1, 0)

उत्तर के लिए 1 № 4

आप अपना फॉर्मूला फिर से लिख सकते हैं

=IF(OR(ISNUMBER(MATCH(CONCATENATE(A2,B2,"MTI"),L:L,0)),
ISNUMBER(MATCH(CONCATENATE(A2,B2,"MTI Z"),L:L,0))),1,0)

संबंधित सवाल
सबसे लोकप्रिय