Excel Wenn Formel mit ODER, vermeiden # N / A - Excel, If-Anweisung, Excel-Formel

Currently facing a problem, long story short:Ich versuche, 2 Formeln zu einem zu kombinieren, indem ich die OR-Funktion verwende, aber wenn eine der beiden Bedingungen nicht existiert, gibt es mir eine # N / A zurück. Es gibt 3 Bedingungen, die passieren können: "MTI", "MTI Z" und "MTO". Was ich möchte ist, dass die Formel nach einer beliebigen Kombination in Spalte L mit entweder "MTI" oder "MTI Z" sucht sei beides) und wenn diese Kombination existiert, gebe eine 1 zurück. Wenn nicht (also nur MTO existiert), dann gebe eine 0 zurück (in diesem Fall ist es eine # N / A, aber ich kann das entweder mit ISNA oder IFERROR beheben) .

Formel 1 ist:

=IF(CONCATENATE(A2,B2,"MTI")=INDEX(L:L,MATCH(CONCATENATE(A2,B2,"MTI"),L:L,0),0),1,0)

Formel 2 ist

=IF(CONCATENATE(A2,B2,"MTI Z")=INDEX(L:L,MATCH(CONCATENATE(A2,B2,"MTI Z"),L:L,0),0),1,0)

Beide Formeln funktionieren und geben eine "1" zurück, wenn es jeweils ein "MTI" oder "MTI Z" gibt

Wenn ich jedoch versuche, sie zu kombinieren, gibt es, wenn 1 der 2 nicht in der Liste vorhanden ist, ein # N / A, obwohl ich OR verwende (was bedeuten würde, wenn mindestens 1 der 2 existiert), gehen Sie geradeaus).

=IF(OR(CONCATENATE(A2,B2,"MTI Z")=INDEX(L:L,MATCH(CONCATENATE(A2,B2,"MTI Z"),L:L,0),0)
,CONCATENATE(A2,B2,"MTI")=INDEX(L:L,MATCH(CONCATENATE(A2,B2,"MTI"),L:L,0),0)),1,0)

Wie kann ich meine Formel so anpassen, dass sie funktioniert?

Antworten:

3 für die Antwort № 1

Das ist ein bisschen geradliniger:

=SIGN(COUNTIF(L:L,CONCATENATE(A2,B2,"MTI*")))

2 für die Antwort № 2

Wickeln Sie jede dieser Formeln in ein IFERROR([formula],0)


1 für die Antwort № 3

Versuchen Sie zwei IFERROR "Wrapper" hinzuzufügen, so dass Sie FALSE zurückgeben, wenn keine Übereinstimmung gefunden wurde, nicht # N / A.

=IF(OR(IFERROR(CONCATENATE(A2,B2,"MTI Z")=INDEX(L:L, MATCH(CONCATENATE(A2,B2, "MTI Z"), L:L, 0)), FALSE),
IFERROR(CONCATENATE(A2,B2,"MTI")=INDEX(L:L, MATCH(CONCATENATE(A2,B2,"MTI"), L:L, 0)), FALSE)),
1, 0)

1 für die Antwort № 4

Sie können Ihre Formel als neu schreiben

=IF(OR(ISNUMBER(MATCH(CONCATENATE(A2,B2,"MTI"),L:L,0)),
ISNUMBER(MATCH(CONCATENATE(A2,B2,"MTI Z"),L:L,0))),1,0)